echo.%* | find “?”>nul2>nul && goto :CLHelp

There are a few things going on here, and reasons for all of them. First is the ‘echo’ command, which just spits out some text to StdOut (StdOut is the logical path to get to the screen). The period ‘.’ immediately following tells echo to send whatever follows, verbatim, and not try to interpret it. This helps in the case that someone just types, ‘yourscript /?’. If the period was not there, echo would interpret the ‘/?’ as a command to itself and would spit out the help for the echo command; not what we’re looking for here.The percent, asterisk combination ‘%*’ returns all of the text on the command line following the name of the script.

So at this point, you have ‘echo.%*’, which just echos the text from the command line back to the screen. The next character, the pipe ‘|’ takes the text that is on its way to the screen, and redirects it to another program. Here, we’re redirecting it to the ‘find’ command, which is searching the text for a question mark. When find finishes running, it reports to the computer, a status code for whether it was successful or not in its task. This is called an errorlevel. An errorlevel of 0 is success. Anything else is almost always a failure code, but these are set by the program creator and could mean anything. As for ‘find’, if it sets an errorlevel of 0, it found the text it was looking for. If it sets an errorlevel of 1, it did not find it.

In this case, we only want to know if a ? was on the line or not. We don’t want to actually see the ? on the screen, so the ‘>nul2>nul’ takes all the text destined for the screen and flushes it down the toilet. Finally, we have the ‘&&’, which reads the most recent errorlevel, and if it is 0, continues with the command following it. If the errorlevel is 1, it skips the command after it. So, if find finds a ? on the command line and sets errorlevel 0, then the && executes the ‘goto :CLHelp’ command, which is appropriate. If the user put a ? on the command line, they want help. Of course, you still need to write the help that the user will get. Here is a very short, simple example.

@echo off
echo.%* | find “?”>nul2>nul && goto :CLHelp
echo You don’t need any help, eh? KNOW-IT-ALL!!!
goto :EOF
:CLHelp
echo So you can’t figure this out on your own? DUMMY!!!

@cscript //Nologo Dec2Hex.vbs

Create a vbs script named Dec2Hex.vbs

Wscript.StdOut.Write "Enter a decimal number to convert (0 to exit): "
strDecimal = Wscript.StdIn.ReadLine

While strDecimal <> 0
Wscript.StdOut.WriteLine ""
Wscript.StdOut.WriteLine "Decimal: " & strDecimal
Wscript.StdOut.WriteLine "Hex: " & Hex(strDecimal)
Wscript.StdOut.WriteLine ""
Wscript.StdOut.Write "Enter a decimal number to convert (0 to exit): "
strDecimal = Wscript.StdIn.ReadLine
Wend

And it looks like this when you’re done:

C:\temp>Dec2Hex.cmd
Enter a decimal number to convert (0 to exit): 255

Decimal: 255
Hex: FF

Enter a decimal number to convert (0 to exit): 16

Decimal: 16
Hex: 10

Enter a decimal number to convert (0 to exit): 65536

Decimal: 65536
Hex: 10000

Enter a decimal number to convert (0 to exit): 0

C:\temp>

Enjoy

rundll32 shell32.dll,ShellExec_RunDLL “MyExcelFile.xls”

echo 1. East Coast
echo 2. MidWest
echo 3. South
echo 4. West Coast
set /p LOCATION=Enter the Location you wish to search:
if “%LOCATION%” == “1″ set SEARCHPATH=c:\locations\east
if “%LOCATION%” == “2″ set SEARCHPATH=c:\locations\midwest
if “%LOCATION%” == “3″ set SEARCHPATH=c:\locations\south
if “%LOCATION%” == “4″ set SEARCHPATH=c:\locations\west

Since this is a simple example, it doesn’t look too complicated. Grow your menu to 20 or 30 choices, and this can quickly become a nightmare to keep up to date. Say you have to add in a new location, “Central”. You might want to insert it between the items currently numbered 3 and 4. You will have to insert that line as menu item 4, change the old 4 to 5, then add a new line between the if statements for 3 and 4, and change the if statement for the old 4 there as well. You can see how this could grow to be unmanagable just adding 5 or 10 more menu options (20 to 40 changes to add a new menu item at position 4, when you already have 14 choices).

Try this on for size. Create this text file first.

East Coast=c:\locations\east
MidWest=c:\locations\midwest
South=c:\locations\south
West Coast=c:\locations\west

Then use this in your script to print the menu and set the LOCATION variable

set MENU=0
for /f “delims== tokens=1,*” %%A in (locations.menu) do (
set /a MENU+=1
set MENUITEM.!MENU!.1=%%A
set MENUITEM.!MENU!.2=%%B
echo [!MENU!] — %%A
)
set /p LOCCHOICE=Enter the Location you wish to search:
for /f %%A in (”%LOCCHOICE%”) do set LOCATION=!MENUITEM.%%A.1! & set SEARCHPATH=!MENUITEM.%%A.2!

Now, before you run away, yes, this looks, and admittedly is, more complicated in this small example we’re dealing with here. The benefits of using this method for your menu show up when you need to make a change. To add that new central location, you have to make one, that’s right, ONE change. Edit the text file that has the menu options in it, and you’re done. Nothing needs changed in the script itself. Even if you have 100 menu choices and you add one more. Just add it, wherever you like in the menu text file, then pack up your stuff and go home. You’re done for the day.

Some more explanation of what is being done is in order though.

Lines 1 – 7 do the work to print out the menu. Look closer, and you will see that they do something else as well. The ’set’ commands are placing each menu item, and the data after the equal sign into a group of variables. In fact, they’re emulating the array structure of more advanced languages. The menu items are being inserted into a 2-dimensional array. Consider the following representation of the array after these 7 lines have been executed.

Lines 8 and 9 take the number that the user enters, then uses that to look up the appropriate row in the array and assign both values to standard variables.

Adding a few lines makes this a complete script, though it doesn’t really do anything useful yet:

@echo off
setlocal ENABLEDELAYEDEXPANSION

set MENU=0
for /f “delims== tokens=1,*” %%A in (locations.menu) do (
set /a MENU+=1
set MENUITEM.!MENU!.1=%%A
set MENUITEM.!MENU!.2=%%B
echo [!MENU!] — %%A
)
set /p LOCCHOICE=Enter the Location you wish to search:
for /f %%A in (”%LOCCHOICE%”) do set LOCATION=!MENUITEM.%%A.1! & set SEARCHPATH=!MENUITEM.%%A.2!

echo.
echo You entered choice %LOCCHOICE% which is menu item %LOCATION% which searches path %SEARCHPATH%

And here’s what it looks like when it runs:

C:\temp>locations.cmd
[1] — East Coast
[2] — MidWest
[3] — South
[4] — West Coast
Enter the Location you wish to search: 2

You entered choice 2 which is menu item MidWest which searches path c:\locations\midwest

Eggs 2.99 7 Big breakfast this weekend
Milk 2.65 9 Only a half gallon left
Bread 1.59 2 Kids out of school next week
Coffee 4.99 4 The only way I’ll be able to get up
Bacon 4.39 6 Again, the big breakfast

Now, that file has all the information you need to go shopping but you don’t really care *why* you’re getting each thing when you’re walking down each aisle. I’ll show you a command to pull just a list of the items you need first.

C:\>for /f %A in (GroceryList.txt) do @echo %A
Eggs
Milk
Bread
Coffee
Bacon

%A is the variable you will store each item in. GroceryList.txt is the text file with all that extra information. The ‘@’ sign in front of ‘echo’ just prevents DOS from showing you the command it’s running. Try it without the ‘@’, you’ll see what I mean.

This is all well and good but you want to know what aisle each item is on as well. Tell ‘For’ that you want the 1st and 3rd item on each line then.

C:\>for /f “tokens=1,3″ %A in (GroceryList.txt) do @echo %A – Aisle %B
Eggs – Aisle 7
Milk – Aisle 9
Bread – Aisle 2
Coffee – Aisle 4
Bacon – Aisle 6

Here, we inserted “tokens=1,3″ to grab the 1st and 3rd item on the line. Note that you don’t have to specify which variable each token gets assigned to. It does that automatically just by incrementing the variable you do choose. If you used the variable %M, then the aisle would be stored in the next letter after M, which would be %N.

The next problem you might run into is what happens when you add a new item to your grocery list, say, “Fruit Juice”. Your output would look like this.

C:\>for /f “tokens=1,3″ %A in (GroceryList.txt) do @echo %A – Aisle %B
Eggs – Aisle 7
Milk – Aisle 9
Bread – Aisle 2
Coffee – Aisle 4
Bacon – Aisle 6
Fruit – Aisle 2.39

We don’t see the word “Juice”, and our Aisle is now the price for that item. Well, that’s because by default, ‘For /F’ uses the space character as the delimiter between tokens. Let’s just reformat our list a little bit and add another customization to the for command to fix that.

Here’s our new text file.

Eggs~2.99~7~Big breakfast this weekend
Milk~2.65~9~Only a half gallon left
Bread~1.59~2~Kids out of school next week
Coffee~4.99~4~The only way I’ll be able to get up
Bacon~4.39~6~Again, the big breakfast
Fruit Juice~2.39~4~Need some Vitamin C

And our new command.

C:\>for /f “delims=~ tokens=1,3″ %A in (GroceryList.txt) do @echo %A – Aisle %B
Eggs – Aisle 7
Milk – Aisle 9
Bread – Aisle 2
Coffee – Aisle 4
Bacon – Aisle 6
Fruit Juice – Aisle 4

Here, we specified that the tilde character “~” would separate tokens instead of the default space.

Jumping into a different example, let’s talk about .ini files. Some programs use them to hold configuration settings. The app reads the .ini file when it opens and sets certain defaults. Doing this with ‘For /F’ is easy. If you have a large complex script that a user might want to change some default values for, create an .ini file and have him change them there, instead of getting in and possibly mucking up your script that you spent so much time and energy getting to run just right. Of course, even in the .ini file, the user may not know what each item is or what to change it to. That’s where the EOL customization comes in. It tells For that if you see this one specific character, to ignore anything else on that line. Here’s an example. I’ll use the semi-colon “;” as the EOL character.

;Set COLOR to 1 if you want a blue screen, 2, if
;you want a yellow screen, or 3 if you want a
;red screen
COLOR=1
;Set SPEED to “Slow” or “Fast”
SPEED=Fast
;Set OUTPUT to “CSV” or “TSV” depending on how you
;would like the results to be formatted
OUTPUT=CSV

In your script, just insert a line similar to this.

C:\>for /f “delims== tokens=1,* eol=;” %A in (Config.ini) do set %A=%B

C:\>set COLOR=1

C:\>set SPEED=Fast

C:\>set OUTPUT=CSV

The “eol=;” part says to ignore anything after the semicolon, so essentially, those are blank lines as far as ‘For’ is concerned. Another thing you may have noticed is the “tokens=1,*”. Specifying an asterisk instead of a token number tells For to take everything else on that line, ignoring the delimiters, and put it all into one variable. So we want token 1 put into variable %A and everything else on the line put into variable %B. I do this in case there is another = sign later in the line that should be included as part of the variable instead of acting like another delimiter.

Remember, when using the ‘For’ command in your scripts, you have to double-up the percent signs. Use %%A instead of %A, etc.

The next post will delve further into For /F, exploring more powerful ways to use it. Stay Tuned

1) The first solution I came up with works, but is very slow. To process a 1000 line file, it took about one and a half minutes to run on my laptop at work.
Read the text file one line at a time, use find to search the output file for the same value.  If not found, insert the current line into that output file.  If it is found, skip.

@echo off
set INFILE=%1
set /p INFILE=Enter the filename of the file to remove duplicates from [%INFILE%]:
set OUTFILE=Unique.txt
copy /y nul %OUTFILE%>nul2>nul
for /f %%A in (%INFILE%) do @type %OUTFILE% | @find /i “%%A”>nul || @echo %%A>>%OUTFILE%
type %OUTFILE%

2) The second solution is more complicated, but runs . . . get this, 40,500 times faster. It completed the same list in two tenths of a second.
This method works by setting an environment variable named for each line in the file, to itself. When a duplicate entry is found, the environment variable is already set so it doesn’t enter it into the output file again.

@echo off

set INFILE=%1
set /p INFILE=Name of the file to remove duplicates from [%INFILE%]:

set OUTFILE=%infile%.out.txt
if exist “%OUTFILE%” del %OUTFILE%

setlocal
setlocal ENABLEDELAYEDEXPANSION

for /f “delims=” %%A in (%INFILE%) do (
if not “!%%A!” == “%%A” echo.%%A>>%OUTFILE%
rem if not “!%%A!” == “%%A” echo.%%A
if not “!%%A!” == “%%A” set %%A=%%A
)

type %OUTFILE%

endlocal

Good Luck!

First, the %RANDOM% variable will always return a random number in the range from 0 to 32767. This is good if you just need to randomize an event. Use the number however you like and be done with it. If however you need a random number that lies in a certain range, say a 6-sided die for instance, there are 32761 numbers that are unusable. The trick is to do a little math with it. Remember back to your elementary school days when you learned about long division and remainders? Let’s take 69 (our random number) divided by 6 (sides on a die). The answer you would get would be 11, remainder 3. If you forget about the 11, the remainder 3 certainly sounds promising. It turns out, any division you do by 6 will actually have a remainder from 0 to 5. Just add one and you have a mathematical formula to generate a random number from 1 to 6. RemainderOf(RandomNumber / 6) + 1 = RandomNumber(1 – 6). Getting the remainder of a division problem is easier than it sounds. Just use the ‘Mod’ operator, “%”, with the Set /A command.

C:\>SET /A RESULT=%RANDOM% % 6 + 1
5
C:\>SET /A RESULT=%RANDOM% % 6 + 1
2
C:\>SET /A RESULT=%RANDOM% % 6 + 1
3

Now you have a method to generate random numbers in any range you wish. If you need a number from 76 – 100, Random Mod 25 plus 76 (set /a result=%random% % 25 + 76)

The second method, using timestamps, is just as easy. Basically, we want to create a string of numbers starting with the largest measurement of time ending at the smallest. That would be year, month, day, hour, minute, second, millisecond. The way to do that is to use variable modifiers explained in the “For” command help. Type “for /?” at the command prompt and look for the section starting with “%~I”. To create the string, do the following:

set RAND=%DATE:~10,4%%DATE:~4,2%%DATE:~7,2%%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%%TIME:~9,2%

The only gotcha here is that the hours from 00:00:00.00 – 09:59:59.99 will have a space at the beginning of the hour instead of a 0. To work around that, just use a small IF-THEN-ELSE statement:

if “%TIME:~0,1%” == ” ” (
set RAND=%DATE:~10,4%%DATE:~4,2%%DATE:~7,2%0%TIME:~1,1%%TIME:~3,2%%TIME:~6,2%%TIME:~9,2%
) ELSE (
set RAND=%DATE:~10,4%%DATE:~4,2%%DATE:~7,2%%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%%TIME:~9,2%
)

set RAND
RAND=2007062700074091

The plus to using this method is that any files that are named using it will have an easy way of telling exactly when the script was run that generated it. This random number was generated in 2007, in June, on the 27th, at 12:07:40.91 AM.

C:\>for /l %A in (1,1,5) do @echo %A
1
2
3
4
5

Looking at the previous example, this statement looks similar to the others, yet has one key difference. The text inside the parentheses is completely different.

The values that go there are, (<Start>,<Increment>,<End>).
<Start> is the number to start with. If this number is not an integer, it will be rounded down.
<Increment> is the quantity to increment the start number by after each loop. This will again be rounded down.
<End> is the number that when it is passed by the Starting number that has been incremented, then loop exits. Again, rounded down if not an int.

The previous example showed the basics of this command, but what can it really do? I’ve used it to generate an At-A-Glance status of available IP addresses on my DHCP server. It could be used to create temporary user accounts for a new classroom of students. Anything where a process needs to be repeated a specific number of times.

The DHCP status example noted above has some lines that queried the server and generated a list of scopes along with the number of free IP addresses for each one. To avoid that complexity in this example, let’s just say that those lines created several environment variables called SCOPE_10.1.1.0 through SCOPE_10.1.10.0 with each one holding the number of free IP addresses.

C:\>set scope_
SCOPE_10.1.1.0=16
SCOPE_10.1.10.0=8
SCOPE_10.1.2.0=148
SCOPE_10.1.3.0=91
SCOPE_10.1.4.0=215
SCOPE_10.1.5.0=24
SCOPE_10.1.6.0=74
SCOPE_10.1.7.0=10
SCOPE_10.1.8.0=206
SCOPE_10.1.9.0=212

I’m going to use the For /F command in this example which will be explained in more detail in a later post. For now, just know that the text inside the For /F loop will get executed for each of the 10 variables.

IMPORTANT: Also note that instead of % signs around some of the variables, I used ! marks. One trick in using the for statement is dealing with the evaluation time of variables. Using % signs, the variables are evaluated and replaced when the initial for statement is read and before any processing takes place. Using ! marks, each variable is evaluated and replaced each time it is used, thus allowing us to set, and then use that value all inside the same for statement. It’s important to note that this functionality is not enabled by default. You must start the cmd executable with the “/v” switch to enable this. I’ll post later a snippet that I put in the beginning of my batch files that need this functionality that makes sure it is enabled.

One other thing you may notice is that I used a value of 4 to increment. I used 4 to make sure that the line of text that gets generated will not be longer than 80 characters, the default for a command prompt window.

@echo off
for /f “delims== tokens=1,2″ %%A in (’set scope_’) do (
set SCOPE=%%A
set LINE=
for /L %%C in (1,4,%%B) do set LINE=!LINE!*
echo !SCOPE:~6! – !LINE!
)

The output will look something like this. An At-A-Glance look at how many free IP addresses you have on each subnet.

C:\>scope
10.1.1.0 – ****
10.1.10.0 – **
10.1.2.0 – *************************************
10.1.3.0 – ***********************
10.1.4.0 – ******************************************************
10.1.5.0 – ******
10.1.6.0 – *******************
10.1.7.0 – ***
10.1.8.0 – ****************************************************
10.1.9.0 – *****************************************************

What else can you do with this? Let me know.

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

Walks the directory tree rooted at [drive:]path, executing the FOR statement in each directory of the tree. If no directory specification is specified after /R then the current directory is assumed. If set is just a single period (.) character then it will just enumerate the directory tree.

In English, it runs your For command, without the /R in every directory under the specified directory.

Going along with the example for /D, let’s say you want more detail in your folder sizes. You want to know how large every folder is as far down as they go:

C:\Batch>for /r c:\batch /d %A in (*.*) do @echo %~fA & @dir /a “%A” | @find “File(s)” & echo.
c:\Batch\Example1
              13 File(s)         4,048,290 bytes

c:\Batch\Example2
               0 File(s)                 0 bytes

c:\Batch\Example3
               4 File(s)           417,093 bytes

c:\Batch\Example1\Disk1
               5 File(s)         1,293,556 bytes

c:\Batch\Example1\Disk2
               4 File(s)         1,630,021 bytes

c:\Batch\Example1\Disk3
               4 File(s)         1,124,713 bytes

c:\Batch\Example2\Disk1
               0 File(s)                 0 bytes

c:\Batch\Example2\Disk2
               0 File(s)                 0 bytes

c:\Batch\Example2\Disk3
               0 File(s)                 0 bytes

c:\Batch\Example3\Disk1
               4 File(s)           417,093 bytes

c:\Batch\Example3\Disk2
               0 File(s)                 0 bytes

1. Insert the CD that came with the camcorder
2. Cancel the setup program that wants to open
3. Plug in the camcorder to AC power and plug the USB cable into the camcorder and computer
4. Vista will open its hardware driver wizard.
5. Let it try to find the drivers on its own.  It will fail and ask you to help it out.
6. Tell it to search your CDROM drive (click the Search Subfolders check box)
7. It should find drivers and tell you it can’t verify the publisher (Which means this probably won’t work on Vista 64-bit)
8. Go ahead and install the driver anyway
9. Navigate to your CDROM drive\USB Media 2.0 directory and run setup.exe
10. Finish this setup program and you should be set.  Open the app and it should find the camcorder and start working immediately.